#| Print the word-frequency count of a file, sorted by frequency.
 | Invoked with one argument (a filename), and prints to stdout.
 | @see http://www.cs.duke.edu/csed/code/, for problem spec.
 | Run with plt-scheme; see 'usage' at end of this file.
 |
 | @author Ian Barland
 | @version 2007.Mar.22
 |#

(require (lib "plt-pretty-big-text.ss" "lang"))
(require (lib "pregexp.ss"))   ; for "split"


;; An "entry" is a dotted-pair, (cons <word> <count>).
;;   For example, (cons "raven" 3) indicates that the word "raven"
;;   has been seen 3 times.

;; Print one entry as a line in the require format.
;;
(define (print-entry e) (printf "~a\t~a\n" (rest e) (first e)))

;; Compare two entries: By decreasing count,
;; with ties broken by increasing words (alphabetically).
;;
(define (entry-greater-than? e1 e2)
  (cond [(> (rest e1) (rest e2)) true ]
        [(< (rest e1) (rest e2)) false]
        [else (string<? (first e1) (first e2))]))


;; Print the frequencies of each word in filename,
;; from most-frequent to least-frequent.
;;
;; This code is not as functional as it could be; the hash table is used
;; to communicate state between different functions.
;;
(define (print-word-frequencies filename)
  (local {
      ;; A hash table to keep track of #occurrences of each word.
      ;; Keys are words; values are the #occurrences.
      (define words (make-hash-table 'equal))
    
      ;; Increment the count for `w'
      (define (add-to-count! word)
        (let* {(w (string-downcase word))}
          (hash-table-put! words w (add1 (hash-table-get words w 0)))))
      }
    
    ;; Accumulate the input frequencies into `words':
    (for-each-word-in-file add-to-count! filename)
    ;; Sort and print `words':
    (for-each print-entry
              (sort (hash-table-map words cons) ; convert hash table into list-of-entries
                    entry-greater-than?))
    ))


;; A generic helper function; an analog to java.util.Scanner's `next()':
;; Invoke `word-handler!' on each word in `filename' (whitespace-delimited).
;;
(define (for-each-word-in-file handle-word! filename)
  (with-input-from-file filename 
    (lambda () (do {[line (read-line) (read-line)]}
                   {(eof-object? line)}
                   (for-each handle-word! (remove "" (pregexp-split "\\s+" line)))))))




;; A test:
;(print-word-frequencies "/Users/ian/Desktop/poe.txt")


;; main:
(print-word-frequencies (vector-ref (current-command-line-arguments) 0))

;;; An alternate main:
;;(if (positive? (vector-length (current-command-line-arguments)))
;;    (print-word-frequencies (vector-ref (current-command-line-arguments) 0))
;;    (for-each (lambda (msg) (printf "Usage:\t~a\n" msg))
;;              '("mzscheme --script word-count.ss input-file.txt"
;;                "(Assumes the input is in `input-file.txt', and the program in `word-count.ss'.)"
;;                "See plt-scheme.org, for downloads."          
;;                )))